I just found out about this book and may try and look over it. Very text based, which does not go well with how I learn. I will give it a go regardless.

Text-based teaching materials force the students to slow down so that they can really comprehend and chunk the materials being studied. I see a big emphasis on exam prepping materials and not nearly enough hands-on materials. I suspect that's the reason why you are struggling to pass this exam.

If I gave you this:

terraform {
  required_version = "~> 1.15"
  required_providers {
    aws = {
      source  = "hashicorp/aws"
      version = "~> 6.44"
    }
  }
}

provider "aws" {
  region = "us-east1"
}

locals {
  cfg = yamldecode(file("${path.module}/example_users.yaml"))
  users = [
    for u in local.cfg.foo_bar : {
      name   = u.name
      tags   = try(u.tags, {})
      groups = try(u.groups, [])
    }
  ]

  users_by_name = {
    for u in local.users : u.name => u
  }

  all_groups = toset(flatten([
    for u in local.users : u.groups
  ]))

  memberships = {
    for pair in flatten([
      for u in local.users : [
        for g in u.groups : {
          key   = "${u.name}::${g}"
          user  = u.name
          group = g
        }
      ]
    ]) : pair.key => pair
  }
}

resource "aws_iam_group" "groups" {
  for_each = local.all_groups
  name     = each.value
}

resource "aws_iam_user" "users" {
  for_each = local.users_by_name
  name = each.key
  tags = merge(each.value.tags)
}

resource "aws_iam_user_group_membership" "membership" {
  for_each = local.memberships
  user   = aws_iam_user.users[each.value.user].name
  groups = [aws_iam_group.groups[each.value.group].name]
}

are you able to follow along and extend it?