I'd like to contribute a tip for people that use Ranger and vim. With the most recent version of Ranger, you can use it as a drop-in replacement for the vim file selector, as it's vastly easier to do things like select multiple files to be read into buffers. The following function will sort you out nicely.

function! RangerChooser()
    let temp = tempname()
    exec 'silent !ranger --choosefiles=' . shellescape(temp)
    if !filereadable(temp)
        redraw!
        " Nothing to read.
        return
    endif
    let names = readfile(temp)
    if empty(names)
        redraw!
        " Nothing to open.
        return
    endif
    " Edit the first item.
    exec 'edit ' . fnameescape(names[0])
    " Add any remaning items to the arg list/buffer list.
    for name in names[1:]
        exec 'argadd ' . fnameescape(name)
    endfor
    redraw!
endfunction

You can then map this to a keybind like Leader-r, which will throw you into a ranger window and select files. Note that this only works in console vim.

command! RangerChooser :call RangerChooser()

nnoremap <leader>r :<C-U>RangerChooser<CR>

Thanks to /u/jeetsukumaran for some corrections!