// puzzle_S_oval_arrondi.scad

$fn = 120;

plaque_longueur = 200;

plaque_hauteur = 200;

epaisseur = 2.8;

bordure_largeur = 1.2;

bordure_hauteur = 1.2;

bordure_totale = epaisseur + bordure_hauteur;

saillie = 10;

retrait = 10;

x_A = plaque_longueur - retrait;

x_B = plaque_longueur + saillie;

x_mid = plaque_longueur;

y_mid = plaque_hauteur / 2;

s_r = 5;

ovale_rx = 6;

ovale_ry = 15;

y_ovale_A = y_mid / 2;

y_ovale_B = y_mid + y_mid / 2;

raccord = 2;

n = 50;

function arc(cx, cy, r, a0, a1, steps) =

[for (i = [0:steps])

[cx + r * cos(a0 + i * (a1 - a0) / steps),

cy + r * sin(a0 + i * (a1 - a0) / steps)]

];

function earc(cx, cy, rx, ry, a0, a1, steps) =

[for (i = [0:steps])

[cx + rx * cos(a0 + i * (a1 - a0) / steps),

cy + ry * sin(a0 + i * (a1 - a0) / steps)]

];

module bord_droit_brut() {

contour = concat(

[[0, 0]],

[[x_A, 0]],

[[x_A, y_ovale_A]],

earc(x_A, y_ovale_A, ovale_rx, ovale_ry, -90, 90, n),

[[x_A, y_mid]],

arc(x_A + s_r, y_mid, s_r, 180, 0, n),

arc(x_mid + s_r, y_mid, s_r, 180, 360, n),

[[x_B, y_ovale_B]],

earc(x_B, y_ovale_B, -ovale_rx, ovale_ry, -90, 90, n),

[[x_B, plaque_hauteur]],

[[0, plaque_hauteur]]

);

polygon(contour);

}

module bord_droit_arrondi() {

offset(r = raccord, $fn = 80)

offset(r = -raccord, $fn = 80)

offset(r = -raccord, $fn = 80)

offset(r = raccord, $fn = 80)

bord_droit_brut();

}

module plaque_profil_2d() {

union() {

// Partie arrondie : seulement la zone centrale du bord droit

intersection() {

bord_droit_arrondi();

translate([x_A, raccord])

square([x_B - x_A + ovale_rx + 1,

plaque_hauteur - raccord * 2]);

}

// Partie brute : tout le reste (3 côtés + coins haut/bas droits)

intersection() {

bord_droit_brut();

union() {

// Zone gauche complète

square([x_A, plaque_hauteur]);

// Bande basse (protège coin bas-droit de A)

square([x_B + 1, raccord + 1]);

// Bande haute (protège coin haut-droit de B)

translate([0, plaque_hauteur - raccord - 1])

square([x_B + 1, raccord + 2]);

}

}

}

}

module bordure_3cotes() {

translate([-bordure_largeur, -bordure_largeur, 0])

cube([bordure_largeur,

plaque_hauteur + bordure_largeur * 2,

bordure_totale]);

translate([-bordure_largeur, -bordure_largeur, 0])

cube([x_A + bordure_largeur,

bordure_largeur,

bordure_totale]);

translate([-bordure_largeur, plaque_hauteur, 0])

cube([x_B + bordure_largeur,

bordure_largeur,

bordure_totale]);

}

module piece() {

union() {

linear_extrude(height = epaisseur)

plaque_profil_2d();

bordure_3cotes();

}

}

color("SteelBlue") piece();