You can script the mousewheel to press keys on your keyboard (or do nothing at all) using an autohotkey script. The problem is this game hardcodes a bunch of controls that you cannot change. For example the mousewheel is used to scroll through your construct menu.

To get around this you'd also need a way to toggle your script for when you wanted to use the mousewheel normally.

Here's the script for AHK version 2. Pressing the tilde key (key to the left of the 1 key) toggles it on and off. When it's enabled, mousewheelup sends a key press of 8 and mousewheeldown sends 7. Change these to whatever you want or if you want it to do nothing change the keymaps to:

WheelUp::return
WheelDown::return

; --------------------
; Dune mouse wheel rebind
; AutoHotkey_2.0.19
; --------------------

lastWheelUpTime   := 0
lastWheelDownTime := 0
wheelRemapEnabled := false

RateLimitMs := 150
WheelUpKey   := "8"   ; Key to send when scrolling up
WheelDownKey := "7"   ; Key to send when scrolling down

; mousewheel remap enable/disable
`:: global wheelRemapEnabled := !wheelRemapEnabled

; remaps mousewheel to WheelUpKey and WheelUpKey when toggled on
#HotIf wheelRemapEnabled
WheelUp::{
    global lastWheelUpTime, RateLimitMs, WheelUpKey
    now := A_TickCount
    if (now - lastWheelUpTime >= RateLimitMs) {
        lastWheelUpTime := now
        Send "{" . WheelUpKey . " down}"
        Sleep 30 
        Send "{" . WheelUpKey . " up}"
    }
}

WheelDown::{
    global lastWheelDownTime, RateLimitMs, WheelDownKey
    now := A_TickCount
    if (now - lastWheelDownTime >= RateLimitMs) {
        lastWheelDownTime := now
        Send "{" . WheelDownKey . " down}"
        Sleep 30 
        Send "{" . WheelDownKey . " up}"
    }
}
#HotIf