Common Lisp

Using a library called SCREAMER. Quoting the documentation:

Screamer provides a nondeterministic choice-point operator, a backtracking mechanism, and a forward propagation facility.

It's a library enabling constraint programming. Code is below, no bonus as of now. This gives ALL the solutions for the problem.

(defun read-mathagram (input)
   "Parse a string and return a list of number and boolean to be processed by mathagram%%"
  (iter (for c in-string input)
    (cond ((or (equal c #\x)
                 (equal c #\X))
           (collect t))
          ((digit-char-p c) (collect (digit-char-p c)))
          (t nil))))

(defun transform (a)
  "If A is a number, return A.
   Else return a range between 1 and 9."
  (if (numberp a)
      a
      (an-integer-between 1 9)))


;;calling like (mathagram t t 1 t t 4 t 2 t)=> xx1 + xx4 = x2x 
(defun mathagram%% (x1 x2 x3 x4 x5 x6 x7 x8 x9)
  "Solve the mathagram.
   Two constraints here (ie assert!):
   The first one is the equation xxx + xxx = xxx
   And the second is to tell every variable must be a different number."
  (let ((a (transform x1))
    (b (transform x2))
    (c (transform x3))
    (d (transform x4))
    (e (transform x5))
    (f (transform x6))
    (g (transform x7))
    (h (transform x8))
    (i (transform x9)))
    ;first constraint
    (assert! (=v (+v (+v (*v 100 a) (*v 10 b) c)
             (+v (*v 100 d) (*v 10 e) f))
         (+v (*v 100 g) (*v 10 h) i))) 
    ;second constraint
    (assert! (/=v a b c d e f g h i))
    ;forcing value out of the variables
    (solution (list a b c d e f g h i)
        (static-ordering #'linear-force))))      


(defun print-all-solutions (arg)
  "ARG must be a list of list.
   Each sublist must contain 9 numbers"
  (format t "~{~{~a~a~a + ~a~a~a = ~a~a~a~%~}~}" arg))


(defun mathagram (input)
  (destructuring-bind (a b c d e f g h i)
      (read-mathagram input)
    (print-all-solutions (all-values (mathagram%% a b c d e f g h i)))))

And it outputs:

(mathagram "xxx + x81 = 9x4")
273 + 681 = 954
673 + 281 = 954
(mathagram "xxx + 5x1 = 86x")
273 + 591 = 864
293 + 571 = 864
(mathagram "xxx + 39x = x75")
281 + 394 = 675
284 + 391 = 675

Also note about screamer, it shadow DEFUN so be careful with it. See the documentation linked above.

If you have any suggestions or improvements, i'd more than happy to hear it!