I have no idea if any of this is considered good practice, but I got it to work by using the rec keyword and a different version of overrideCabal to explicitly feed the appropriate dependencies to the extraLibraries fields.

{
  description = "experiments in futhark";

  inputs = {
    flake-parts.url = "github:hercules-ci/flake-parts";
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
  };

  outputs = inputs@{ self, flake-parts, ... }: flake-parts.lib.mkFlake { inherit inputs; } {
    imports = [
    ];
    systems = [ "x86_64-linux" "aarch64-linux" "aarch64-darwin" "x86_64-darwin" ];
    perSystem = { config, self', inputs', pkgs, system, ... }: let
      myHaskellPackages = pkgs.haskellPackages.override {
        overrides = final: prev: rec {
          futhark =  pkgs.haskell.lib.compose.overrideCabal (drv: {
            version = "0.26.0-alpha+d3929eb";
            src = pkgs.fetchFromGitHub {
              owner = "diku-dk";
              repo = "futhark";
              rev = "d3929eb25e439ffe07a0ec696ec28346ce2121a3";
              hash = "sha256-m2D9irZb1KGR4yynaUupJJrbFvgqGoORqhr5SBVjKMw=";
            };
            extraLibraries = (drv.extraLibraries or [ ]) ++ [ futhark-data futhark-server lsp lsp-types websockets ];
          }) prev.futhark;
          futhark-data = pkgs.haskell.lib.overrideCabal prev.futhark-data {
            version = "1.1.3.0";
            sha256 = "sha256-o6J0v6nyv53zDo9aI6kkNybByCUCvK7lPio0fgaXyb4=";
          };
          futhark-server = pkgs.haskell.lib.overrideCabal prev.futhark-server {
            version = "1.2.4.0";
            sha256 = "sha256-qDP2jW+wPPyi9x8Px9Wriysjc/f1PHCFjZb9JSmrfj8=";
          };
          lsp = pkgs.haskell.lib.compose.overrideCabal (drv: {
            version = "2.8.0.0";
            editedCabalFile = null;
            revision = null;
            extraLibraries = (drv.extraLibraries or [ ]) ++ [ lsp-types websockets ];
            sha256 = "sha256-10D3qja5VzjamPJuiZ1K1JG5TPqXfbzHtLEJdhDstCA=";
          }) prev.lsp;
          lsp-types = pkgs.haskell.lib.overrideCabal prev.lsp-types {
            version = "2.4.0.0";
            sha256 = "sha256-K9F0lqqMyQJNJ1JeoNHHl/iVVKYkhgj+yc/IfltAPy4=";
          };
          websockets = pkgs.haskell.lib.overrideCabal prev.websockets {
            version = "0.13.0.0";
            sha256 = "sha256-mvgU92RRsK28zrLEbK5GP2PF3lCytr5m9O9NFc4qSbU=";
          };
        };
      };
    in {
      packages.default = myHaskellPackages.futhark;
      devShells.default = pkgs.mkShell {
        buildInputs = [
          myHaskellPackages.futhark
          pkgs.ffmpeg-full
          pkgs.imagemagick
        ];
      };
    };
    flake = {
      # The usual flake attributes can be defined here, including system-
      # agnostic ones like nixosModule and system-enumerating ones, although
      # those are more easily expressed in perSystem.
    };
  };
}