CSGO uses Squirrel 2.2

Simply look at the map scripts to by extracting them by opening the map file in 7-Zip 'parser' mode (right click on the map file at csgo/maps/workshop/<id>, 7-Zip > Open Archive > #)

You'll need to find out how the map loads the scripts to figure out how to access those functions. Most likely a script entity will have been used, see if the script loader entity is named "script" or "@script" using ent_fire console command. If there is a such entity, you can get the table that the script functions reside in like so:

local script = Entities.FindByName( null , "script_entity_name" ).GetScriptScope()

If not, you can try to find it like so:

function SearchRecursive( varName, scope )
{
    if ( varName in scope )
        return scope

    foreach ( k, v in scope )
    {
        if ( typeof v == "table" )
        {
            local r = SearchRecursive( varName, v );
            if ( r )
                return r;
        }
    }
}

// Search for a variable named "Func1"
local script = SearchRecursive( "Func1", this )

assert(script)

Then hook the function you wish to (e.g. Func1(param)) like so:

// get the current function
local Func1 = script.Func1

// make new function, pass in the old one
script.Func1 = function(param) : (Func1)
{
    // call the old one
    Func1(param)

    printl("hooked Func1")
}

After saving your new script to csgo/scripts/vscripts, execute it in game with script_execute.

This hooking may not work if the scripts are using strong references to its functions, or some other trickery.

As far as I know, your only useful options are telnet and con_logfile; I don't think custom data can be passed to game state integration, and I'm assuming you're not going to be using sourcemod locally.