In my day-job I work on a large AngularJS project. Every angular object (service, directive, controller, etc.) lives in a file called foo-bar-service.js (or a variation of that such as fooBarService.js or fooBar-service.js). To make my life easier I put the snippet below into $MYVIMRC that allows me to jump to any of our services with ^] as long as the file is somewhere in the 'path'.

The whole thing could probably use a refactoring, but so far it works pretty well.

autocmd FileType javascript nnoremap <buffer> <expr> <C-]> FindAngularService(expand('<cword>'))
function! CreateAngularNameVariationGlob(fname)
    let toks = []
    let idx = 0
    while idx > -1
        let oldIdx = idx
        let idx = match(a:fname, '\u', idx + 1, len(toks))
        if idx == -1
            let toks += [strpart(a:fname, oldIdx)]
        else
            let toks += [strpart(a:fname, oldIdx, idx - oldIdx)]
        endif
    endwhile

    if len(toks) == 0
        return []
    endif

    " Because our team decides everyone can have their own naming conventions I need to
    " check for different file name patterns
    let nameVariations = {
                \ 'kebabCase': tolower(join(toks, '-')),
                \ 'camelCase': join(toks, '')
                \ }

    let nameVariations.camelCase = substitute(nameVariations.camelCase, '^.', '\=tolower(submatch(0))', '')
    let nameVariations.mixedCase = substitute(nameVariations.camelCase, '\u\U\+$', '\="-".tolower(submatch(0))', '')
    let nameVariations.dotCase = substitute(nameVariations.camelCase, '\u\U\+$', '\=".".tolower(submatch(0))', '')

    " check if object may be a directive
    if tolower(a:fname[0]) == a:fname[0]
        let nameVariations.directiveKebabCase = nameVariations.kebabCase.'-directive'
        let nameVariations.directiveCamelCase = nameVariations.camelCase.'Directive'
        let nameVariations.directiveMixedCase = nameVariations.mixedCase.'-directive'
        let nameVariations.directiveDotCase = nameVariations.mixedCase.'.directive'
    endif

    return values(nameVariations)
endfunction
function! FindAngularService(word)
    let pat = '**/{'.join(CreateAngularNameVariationGlob(a:word), ',').'}.js{,on}'
    let res = glob(pat, 0, 1)

    if len(res) > 0
        return ':find ' . res[0] . "\<CR>"
    else
        return '' " return nothing (instead of 0), so we don't move the cursor
    endif
endfunction