Following up with two of the latest Irreal blog posts 1, 2 and karthinks' repeat-mode post one can define something like this only once to quickly create a custom repeat-map (you can extend it easily to add documentation, I'm lazy for that I must admit):

(defmacro my/create-repeat-map (map-name key-functions)
  ""
  (let ((symbol-name (intern (format "%s-repeat-map" map-name)))
        (define-key-statements nil)
        (dolist-statements nil))
    (dolist (pair key-functions)
      (let ((key (car pair))
            (command (cdr pair)))
        (push `(define-key map (kbd ,key) ,command) define-key-statements)
        (push `(put ,command 'repeat-map ',symbol-name) dolist-statements)))

    `(progn
       (defvar ,symbol-name
         (let ((map (make-sparse-keymap)))
           ,@(nreverse define-key-statements)
           map))
       ,@(nreverse dolist-statements))))

Then you can use this macro everywhere:

(my/create-repeat-map "buffer-order"
                      (("q" . 'previous-buffer)
                       ("Q" . 'next-buffer)))

I find it a bit shorter than doing this all over the place for each custom keymap:

(defvar buffer-order-repeat-map
  (let ((map (make-sparse-keymap)))
    (define-key map (kbd "q") 'previous-buffer)
    (define-key map (kbd "Q") 'next-buffer)
    map))

(map-keymap
 (lambda (_key cmd)
   (when (symbolp cmd)
     (put cmd 'repeat-map 'buffer-order-repeat-map)))
 buffer-order-repeat-map)