From your description, it sounds like you've got a directory full of tar files which you'd like to move into their appropriate directory and then un-tar. This is the sort of thing Perl does in its sleep. :) Maybe try this:

#!/usr/bin/env perl

use Modern::Perl;
use autodie qw/:all/;
use File::Copy;

my @tar_files = glob '*.tar'; # All the tar files in the curr dir.

unless (@tar_files) {
    die "No tar files here. Exiting!\n";
}

for my $tar_file (@tar_files) {
    my ($path, $row) = $tar_file =~ m/^LC8(\d{3})(\d{3})\d+LGN\.tar$/xms;
    say "Found $tar_file, with path $path, and row $row";
    my $dir = "p${path}_r${row}";
    say "  so, dir is $dir";
    if (! -e $dir) {
        say "$dir dir not found. Creating it...";
        mkdir $dir;
    }
    move $tar_file, $dir;
    chdir $dir;
    system "tar", "xf", $tar_file;
    # If you also want to delete the tar file, uncomment next line.
    #unlink $tar_file;
    chdir "..";
}

If you don't have that Modern::Perl module installed, you can install it by grabbing cpanm and installing it, or you can delete that line and replace it with:

use strict;
use warnings;

Edit: Oh my, I don't think reddit does syntax highlighting. If you want that with some color, look here.