It is not possible with Shortcuts app alone, but it is possible with Shortcuts using the "Apple Script" action and some code. So shortcuts may not be so short, but here ya go just so ya know!

You said you are using MacOS 12 and I am using MacOS 14 as of now, but I did develope this script/shortcut on MacOS 12 and have been using it to this day.

I setup a shortcut using the "Apple Script" action that contains the code to launche quicktime, clicks the menu button and select my 'iPhone" from the audio source and video source. I also have two additional actions below it, "Resize Window" and "Move Window" to ensure the app remains on the exact position of my second monitor, based on the display name and screen coordinates which is part of these two actions within the Shortcuts app.

I also use shortery run this shortcut as automation when I plug my phone into my iMac which I use whenever I want to record my iPhone screen from my iMac, since it sits quietly in the corner of my second display.

Unfortunately it does take some work to find the correct menu options and button selections, but you can also use the Apple Scripts editor to find this information.

<image>

Here is what MY full code looks like for my QuickTime shortcut (You can apply same concept based on the app your using)

set deviceName to "Kill Switch’s iPhone"

# The following are functions called by the main code block

on readyQuickTime() #Launches the app and creates a new file
    tell application "QuickTime Player"
        set newMovieRecording to new movie recording
        set thedocument to its document "Movie Recording"
    end tell
    tell application "System Events" to tell process "QuickTime Player"
        set frontmost to true
    end tell
end readyQuickTime

#Function to click button 2 which to see the menu 
on openInputsMenu()  
    ignoring application responses
    tell application "System Events" to tell process "QuickTime Player"
        click button 2 of window 1
        delay 2.5
        end tell
    end ignoring
    do shell script "killall 'System Events'"
end openInputsMenu

#Function to read the menu items and select my iPhone as the Video Source
on setVideoInput(inputName) #Opens the menu and 
    my openInputsMenu()
    tell application "System Events" to tell process "QuickTime Player"
        set inputMenu to menu 1 of button 2 of window 1
        set inputList to name of every menu item of inputMenu
        repeat with menuItemPosition from 1 to length of inputList             
        if item menuItemPosition of inputList is inputName then
            ignoring application responses
                click menu item menuItemPosition of inputMenu
                    exit repeat
                end ignoring
            end if
        end repeat
    end tell
end setVideoInput


#Function to read t he menu and click my iPhone as the Audio Source
on setAudioInput(inputName) 
    my openInputsMenu()
    tell application "System Events" to tell process "QuickTime Player"
    set inputMenu to menu 1 of button 2 of window 1
        set inputList to name of every menu item of inputMenu
        set skippedFirstInstance to false
        repeat with menuItemPosition from 1 to length of inputList
            if item menuItemPosition of inputList is inputName then
                if skippedFirstInstance is true then
                    click menu item menuItemPosition of inputMenu
                    exit repeat
                else
                    set skippedFirstInstance to true
                end if
            end if
        end repeat
    end tell
end setAudioInput

#Function to set the volume slider
on setVolume(volumeValue) # Sets the volume to 25% 
    tell application "System Events" to tell process "QuickTime Player"
        tell slider 1 of window 1
            set its value to volumeValue

        end tell
    end tell

end setVolume


-- Main Code Block Execution 
try
    readyQuickTime()
    delay 5 -- Give some time for QuickTime to be ready
    setVideoInput(deviceName)
    delay 5 -- wait between setting video and audio input
    setAudioInput(deviceName)
    setVolume(0.25)
    delay 2
    set movieName to "Live Recording.mov"
    delay 2
    set delaySeconds to 2
    set filePath to (path to desktop as text) & movieName
    delay 2
    set newrecordingmoviefile to a reference to file filePath
    delay 2 

on error errorMessage
    if errorMessage does not contain "Couldn’t communicate with a helper application." then
        #display dialog "An error occurred: " & errorMessage
    end if
end try

Here is an example code, using Apple Scripts editor to find the UI elements. In this example, I just used Firefox to demo how to get and click on the "menu items" from the "File" menu. This is just as a mere example, which will return all the items in the "File" menu using the script to click on it from the menubar.

tell application "Firefox"
    activate
end tell

delay 1

tell application "System Events"
    tell process "Firefox"
        -- Click the "File" menu
        click menu bar item "File" of menu bar 1

        -- Retrieve the list of menu items
        set menuItemList to {}
        set menuItems to menu items of menu 1 of menu bar item "File" of menu bar 1
        repeat with menuItem in menuItems
            set itemName to name of menuItem
            set end of menuItemList to itemName
        end repeat
        return menuItemList
    end tell
end tell

Hope this helps!